Date : 10-12-93      Time : 10:02    Status : Public - Unread
From : George Hug                    Subj   : CRC-32                   
To   : Rod Gasson                    Area   : CBM-128      

In case you might need it, here is a replacement for the subroutine
I sent you for running a byte through the CRC-32 algorithm. This one
does not use a lookup table, so it saves about 1K in memory usage,
but it also takes about 10 times as long to do the calculation.

crcsub  sta temp
        ldx #8
loop    lsr crc3
        ror crc2
        ror crc1
        ror crc0
        ror temp
        ror
        eor temp
        bpl doloop
        lda crc3
        eor #$ed
        sta crc3
        lda crc2
        eor #$b8
        sta crc2
        lda crc1
        eor #$83
        sta crc1
        lda crc0
        eor #$20
        sta crc0
doloop  dex
        bne loop
        rts

As with the lookup table version, the locations crc0 - crc3 should
be initialized to #$FF, and the final crc value EORed with #$FFs.

--- EZQuote
 * Origin: Frostbite Falls (1:170/110.8)