10 rem ***** identify disk drives *****  rod gasson 21/11/95
20  : 
30 for dv=8 to 16
40  : 
50 open15,dv,15 : close15 : 
60 if st= -128  then print "device"dv"Not online"  : goto420
70  : 
80 open 15,dv,15
90 print#15,"m-r"chr$(164)chr$(254)chr$(2) : get#15,a$,b$
100  : 
110 print chr$(14)"device"dv"is a";
120  : 
130 if a$="h" and b$= "d" then  print" CMD Hard Drive";  : goto190
140 if a$="r" and b$= "d" then  print" CMD Ram Drive";  : goto190
150 if a$="f" and b$= "d" then  print" CMD FDxx";      : goto190
160 if a$="r" and b$= "l" then  print" CMD Ramlink";   : goto190
170 goto 310
180  : 
190 print " in ";
200  : 
210 print#15,"g-p"  :  get#15,x$ :  x=asc(x$+chr$(0))
220  : 
230 if x=1 then print  "Native";
240 if x=2 then print  "1541 emulation";
250 if x=3 then print  "1571 emulation";
260 if x=4 then print  "1581 emulation";
270 if x=5 then print  "CP/M emulation";
280 if x=7 then print  "DACC";
290 print " mode"  :  goto420
300  : 
310 print#15,"m-r"chr$(233)chr$(166)chr$(2) : get#15,a$,b$
320 if a$=chr$(56) and b$= chr$(177) then print" 1581"   : goto420
330  : 
340 print#15,"m-r"chr$(198)chr$(229)chr$(2) : get#15,a$,b$
350  : 
360 if a$=chr$(52) and b$= chr$(177) then print" 1541"    : goto420
370 if a$=chr$(55) and b$= chr$(177) then print" 1571"    : goto420
380 if a$=chr$(56) and b$= chr$(182) then print" 64 net"  : goto420
390  : 
400 print "unknown drive"
410  : 
420 close15  : next